Dynamic Multiple Choice Field - How to Programmatically Assign

Yes, I shouldn't have said random. I was able to replicate the selections of a Dynamic Multi Choice of one record in another by feeding in that string. It's clear something that's coded, but I couldn't begin to decode it. Plus, I'm linking dynamically to a table of 200+ records (every iso2 country!). And I also noticed that chosen() doesn't work on the Dynamic fields. 

Thanks for pointing out the hexadecimal encoding. It's new territory for me but I'll have a crack at it.

 

Hopefully Ninox allow pushing an Array of IDs into a Dynamic Multi Choice field at some point...

This is super helpful. I can now draft hex strings and get the expected results to show. Now on to the work to write a script that will do that for me programmatically!!

This is a script I've got working for me at the moment... it's a bit "hack-y" so I can't say how robust it will be but it's proven excellent for my use case. I have 1000+ records of companies with a Text Field that contains iso2 country codes for where offices are based, e.g. "CN, DE, NL, US". I was able to use this function to programmatically convert those to the correct DYNAMIC multiple choices, which link to a table called Countries, where each record has an iso2 country code and the corresponding country name.

 

If you choose to use this code, note you will have to tweak TABLE NAMES and FIELD NAMES, which I've had to hard code, as Ninox doesn't allow these to be passed into functions themselves. I'm sure someone is capable of producing something neater...

 

"// Accepts a stringified array of iso2 country codes and generates a hex string for passing into a dynamic multi choice field";
function generateHexStringCountries(stringifiedArray : text) do
    let allCountries := (select Countries);
    let splitArray := split(stringifiedArray, ",");
    let splitArray := for i in splitArray do trim(i) end;
    let choiceRecordIDs := for i in splitArray do
        let choice := allCountries[Code = i];
        let recordID := choice.Id;
        recordID
    end;
    let orderedRecordIDs := for c in choiceRecordIDs order by number(Id) do
        c
    end;
    let dictArray := for recordID in orderedRecordIDs do
        "// rounds up to determine which positional group it's in";
        let hexgroup := ceil(number(recordID) / 4);
        "// checks remainder to determine its position within group";
        let posString := number(recordID) % 4;
        let weighting := switch posString do
            case 1: 1
            case 2: 2
            case 3: 4                                                                                                    case 0: 8
        end;
        let choicePosWeightDict := {
            pos: number(hexgroup),
            weight: weighting
        };
        choicePosWeightDict
    end;
    "// with length of hexstring determined, make an array returning a weight for each position along the hexstring";
    let hexLength := max(for i in dictArray do
        i.pos
    end);
    let hexArray := for item in range(1, number(hexLength) + 1) do
        let weightValue := 0;
        "// iterates through each dict and returns the sum of all weights that match pos";
        last(for dict in dictArray do
            if item = dict.pos then
                weightValue := weightValue + number(dict.weight)
            end;
            let weightEncoded := switch weightValue do
                case 10: "a"
                case 11: "b"
                case 12: "c"
                case 13: "d"
                case 14: "e"
                case 15: "f"
                default: text(weightValue)
            end;
            text(weightEncoded)
        end)
    end;
    "// turn that array to a string and return";
    let hexString := join(hexArray, "");
    hexString
end

Interesting, that is rather bizarre behaviour. Haven't tested it myself.

 

Inspired by Sean's post, I realised I should have separated the logic for 1) grabbing a list of record IDs from a table based on certain criteria and 2) passing an array of record IDs into a hexstring generator. 

 

The code snippet pasted below, stored as a global variable, should permit the following usage:

 

populateDMC("1")

# returns "1"

populateDMC("1, 2, 3, 4")

# returns "f"

populateDMC("1, 2, 3, 4, 41, 42, 43, 44")

# returns "f000000000f"

 

DMC := populateDMC("1, 2")

is the same as

DMC := "3"

which will select records with ids 1 and 2 in your dynamic multi choice field

 

"// Accepts a stringified array of record id numbers and generates a hex string for passing into a dynamic multi choice field";
function populateDMC(stringifiedArray : text) do
let idArray := split(stringifiedArray, ",");
idArray := for i in idArray do
trim(i)
end;
let dictArray := for recordID in idArray do
"// rounds up to determine which positional group it's in";
let hexgroup := ceil(number(recordID) / 4);
"// checks remainder to determine its position within group";
let posString := number(recordID) % 4;
let weighting := switch posString do
case 1:
1
case 2:
2
case 3:
4
case 0:
8
end;
let choicePosWeightDict := {
pos: number(hexgroup),
weight: weighting
};
choicePosWeightDict
end;
"// with length of hexstring determined, make an array returning a weight for each position along the hexstring";
let hexLength := max(for i in dictArray do
i.pos
end);
let hexArray := for item in range(1, number(hexLength) + 1) do
let weightValue := 0;
"// iterates through each dict and returns the sum of all weights that match pos";
last(for dict in dictArray do
if item = dict.pos then
weightValue := weightValue + number(dict.weight)
end;
let weightEncoded := switch weightValue do
case 10:
"a"
case 11:
"b"
case 12:
"c"
case 13:
"d"
case 14:
"e"
case 15:
"f"
default:
text(weightValue)
end;
text(weightEncoded)
end)
end;
"// turn that array to a string and return";
let hexString := join(hexArray, "");
hexString
end

As I understand it, numbers(DMC) just returns an array with the IDs of the records in the table to which the DMC is linked. If you call DMC without numbers() just as it is, or call it with a raw() function, you'll see a hexadecimal representation of the multi choice selection, as explained by Alain.

Check the Table you are linking too... you may have deleted the records in that table with ID 1 and 2. as Alain noted a few posts ago, even if you delete those, they may still show as selected - even though there is nothing to select.

 

As a fix, you could attempt the following, using the code snippet I attached earlier as a global function.

 

myDMCField := populateDMC("12, 15, 18, 19")

 

That should get rid of 1 and 2?