how to project this db

stef. idea said:
Ok.The dropdown (or radio) with 100-150 client on a mobilephone (the operator is moving around and will use a smartphone) it isn't very hand.

 That is very true. I’m glad to hear you have so many customers.

I can do the delivery section to look like the kitchen, just that the button would do slightly different things.

I’ll also see how to do multiple scanning, so your boss can scan to her hearts content.

Ok take a look at v3. I changed delivery to returns. There is the item/quantity options and the multi scan option. I left the view element so you can see it working.

In the end should give you an idea if Ninox is right for your requirements.

stef. idea said:
with apple, you didn't need to do anything special to have barcode reading, right?it just works?

 that is correct. no special software needed.

stef. idea said:
For the graph/statistici the table where start from is MOVIMENTI i suppose?

That is correct. Take another look at the db file I upload a few days ago to see samples of some codes.

stef. idea said:
where i can select form a dropdown menu the client, the product id and the range of time and have returned different statistics?

 Yes you can do this. The Quick Form table shows you an example of how to do it with a month selection. But you can do dynamic choice fields so you can get data from your clients, products and time.

Take a look at v4. I’ve updated the Quick View table to show one way of doing the data analysis.

there is a hidden field called gatherData that figures out the which fields got used and then to find the appropriate data. 

with this method, you can then create the summary fields and just reference gatherData to get your results. Like Total Sold would be:

sum(gatherData.Vendite.Sold)

The code for gatherData, is the most elegant way about it but it works.

let t := this;
let startCheck := if 'Start Date' != null then 1 end;
let endCheck := if 'End Date' != null then 2 end;
let yearCheck := if year != null then 3 end;
let monthCheck := if Month != null then 4 end;
let custCheck := if Customer != null then 5 end;
let dataEntryCheck := [startCheck, endCheck, yearCheck, monthCheck, custCheck];
let gatherMovimenti := (select Movimenti);
switch true do
case contains(dataEntryCheck, 3) and contains(dataEntryCheck, 4) and
contains(dataEntryCheck, 5):
    gatherMovimenti[year = text(t.year) and monthNum = t.Month and '2_Clients' = number(t.Customer)]
case contains(dataEntryCheck, 1) and contains(dataEntryCheck, 2) and
contains(dataEntryCheck, 5):
    gatherMovimenti['Order date' >= t.'Start Date' and 'Order date' <= t.'End Date' and
        '2_Clients' = number(t.Customer)]
case contains(dataEntryCheck, 1) and contains(dataEntryCheck, 2):
    gatherMovimenti['Order date' >= t.'Start Date' and 'Order date' <= t.'End Date']
case contains(dataEntryCheck, 1) and contains(dataEntryCheck, 5):
    gatherMovimenti['Order date' >= t.'Start Date' and '2_Clients' = number(t.Customer)]
case contains(dataEntryCheck, 2) and contains(dataEntryCheck, 5):
    gatherMovimenti['Order date' <= t.'End Date' and '2_Clients' = number(t.Customer)]
case contains(dataEntryCheck, 3) and contains(dataEntryCheck, 4):
    gatherMovimenti[year = text(t.year) and monthNum = t.Month]
case contains(dataEntryCheck, 3) and contains(dataEntryCheck, 5):
    gatherMovimenti[year = text(t.year) and '2_Clients' = number(t.Customer)]
case contains(dataEntryCheck, 4) and contains(dataEntryCheck, 5):
    gatherMovimenti[monthNum = t.Month and '2_Clients' = number(t.Customer)]
case dataEntryCheck[= 1]:
    gatherMovimenti['Order date' >= t.'Start Date']
case contains(dataEntryCheck, 2):
    gatherMovimenti['Order date' <= t.'End Date']
case contains(dataEntryCheck, 5):
    gatherMovimenti['2_Clients' = number(t.Customer)]
case contains(dataEntryCheck, 4):
    gatherMovimenti[monthNum = t.Month]
case contains(dataEntryCheck, 3):
    gatherMovimenti[year = text(t.year)]
end

Line 1: assigns the current record into the variable “t”.

Lines 2 - 6: assigns a variable for each possible selection field and then assigns a unique number if the field is NOT null.

Line 7: creates an array with the variables from lines 2 - 6.

Line 8: get all of the data from the other table into a variable to be used later

Lines 9 - 39: uses the switch function to check the array from line 7 to figure out what combination of fields we need to filter our data.

I was reminded, from testing, that a switch function goes down the list and stops at the first instance of true. Which means you need to put the multi selection check first before the single selection check otherwise it will always stop at the single since that will return true.

In other words I need to put the check for Start Date and End Date and Customer before I check for Start Date and End Date and before I check for Start Date.

I am hoping others can find a more elegant (fewer lines of code) way of doing this.